, , , Utilisation d’invite sélective

Vous connaissez et utilisez l’API QCMDEXC qui permet d’exécuter un commande IBMI

Exemple

CALL QCMDEXC (‘ADDLIBLE STITE’ 25)

Vous pouvez utilisez aussi par SQL sous forme de fonction ou procédure

Et enfin elle sera utilisée si vous faites un menu par SDA ou par UIM

Pour avoir une invite sélective vous devrez indiquer un ? avant la commande

Exemple


?WRKSPLF

Pour exécuter la commande WRKSPLF en ayant un invite équivalent à si vous aviez utilisé <F4>

Mais vous pouvez vouloir que certain paramètres soient affichables sans saisie d’autre pas affichable etc …

On va pouvoir indiquer devant les paramètres de la commande 2 caractères, pour indiquer une option de traitement de l’invite

?? le paramètre est modifiable et visible
?* le paramètre est vue mais pas modifiable
?– le paramètre n’est pas affichée

Ci dessous un tableau récapitulatif

Exemple

Sur la commande de gestion des fonctions usage , dans une procédure SQL

Ce qui produira un résultat suivant ou les 2 paramètres DEFAULT et ALLOBJAUT ne seront pas affichés

Le lien à connaitre pour les informations complètes

https://www.ibm.com/docs/en/i/7.3?topic=time-using-selective-prompting-cl-commands

/par
, , , Informations sur les commandes

Avec la version TR1 de 7.5 et la TR7 de la 7.4

IBM met à dispo un service (COMMAND_INFO) qui va permettre d’avoir des informations sur les commandes de votre partition IBM i.

Voici 2 idées d’utilisation de cette vue QSYS2.COMMAND_INFO

Par exemple, pour connaitre les commandes qui sont permises en environnement restreint

SELECT *
FROM QSYS2.COMMAND_INFO
WHERE ALLOW_LIMITED_USER = ‘*YES’

Par exemple, pour savoir si un programme est utilisé dans une commande lorsqu’on fait une analyse d’impact avant une modification

SELECT COMMAND_NAME,
COMMAND_PROCESSING_PROGRAM_LIBRARY,
COMMAND_PROCESSING_PROGRAM
FROM QSYS2.COMMAND_INFO
WHERE COMMAND_LIBRARY = ‘GFTP’

Conclusion :

Cette vue fournit des informations intéressantes et faciles à croiser avec d’autres éléments sur toutes les commandes présentes sur vos systèmes.

/par
,

Création de programmes de service

Lorsque l’on crée un programme de service il est intéressant de classer les procédures utilisées dans différents modules afin de faciliter une maintenance future. On peut regrouper par exemple les procédures par fonctionnalité métier (prise de commandes, rangement, calculs de taux,… ) ou par proximité technique (manipulation de chaines de caractères, calcul d’un modulo, manipulation de dates,… ). Dans l’article intitulé « CONTROLER IBAN & RIB » on regroupe les deux fonctions bancaires au sein d’une même procédure.

Lorsque l’on veut créer un programme de service il faut procéder en deux temps :

  • Créer les modules contenant les procédures et fonctions 
CRTSQLRPGI OBJ(MyLibrary/MyModuleXX) SRCFILE(MyLibrary/MySRCPF) SRCMBR(MyModuleXX) OBJTYPE(MODULE) REPLACE(YES) DBGVIEW(*SOURCE)
  • Créer le programme de service qui intègrera les modules
CRTSRVPGM SRVPGM(MyLibrary/MyServicePGM) MODULE(MyLibrary/MyModule0 MyLibrary/MyModule1 MyLibrary/MyModule2 MyLibrary/MyModule3 MyLibrary/MyModule4) EXPORT(*SRCFILE) SRCFILE(MyLibrary/QSRVSRC) SRCMBR(MySrcMBR)

Nous vous proposons donc de créer une fonction qui permettra d’enchainer ces deux opérations (nous nous limiterons à la possibilité d’agréger 10 modules dans un programme de service)

Présentation de la commande

Cette commande permet de saisir plusieurs modules et de les intégrer directement dans un programme de service

On peut également ajouter un répertoire de liage, si besoin

Source de la commande

             CMD        PROMPT('Création Programme de Service')
             PARM       KWD(SRVPGM) TYPE(Q0) MIN(1) PROMPT('Programme de service ')
 Q0:         QUAL       TYPE(*NAME) LEN(10) MIN(1)
             QUAL       TYPE(*NAME) LEN(10) DFT(*CURLIB) SPCVAL((*CURLIB)) MIN(0) +
                          PROMPT('Bibliothèque           ')
             PARM       KWD(SRVSRC) TYPE(Q1) PROMPT('Fichier source d''exportation')
 Q1:         QUAL       TYPE(*NAME) LEN(10) DFT(QSRVSRC) MIN(0)
             QUAL       TYPE(*NAME) LEN(10) DFT(*CURLIB) SPCVAL((*CURLIB)) MIN(0) +
                          PROMPT('Bibliothèque           ')
             QUAL       TYPE(*NAME) LEN(10) DFT(*SRVPGM) SPCVAL((*SRVPGM)) MIN(0) +
                          PROMPT('Membre source d''exportation')
             PARM       KWD(MODULE) TYPE(*NAME) LEN(10) MAX(10) PROMPT('Modules du Programme ')
             PARM       KWD(SRCFIL) TYPE(*NAME) LEN(10) MIN(0) DFT(QRPGLESRC) PROMPT('Fichier +
                          source Programme ')
             PARM       KWD(ONBNDDIR) TYPE(*CHAR) LEN(1) MIN(0) PROMPT('Répertoire de Liage O/N  ')
             PARM       KWD(BNDDIR) TYPE(*NAME) LEN(10) MIN(0) PMTCTL(LIAGE) +
                          PROMPT('Répertoire de Liage  ')

 LIAGE:      PMTCTL     CTL(SRCFIL) COND((*NE '')) NBRTRUE(*ALL)
             PMTCTL     CTL(SRVSRC) COND((*NE '')) NBRTRUE(*ALL) LGLREL(*AND)
             PMTCTL     CTL(ONBNDDIR) COND((*EQ 'O')) NBRTRUE(*ALL) LGLREL(*AND)
 LIAG2:      PMTCTL     CTL(ONBNDDIR) COND((*EQ 'O') (*EQ 'N')) NBRTRUE(*EQ 1)

Programme de controle

PGM        PARM(&SRVPGMLIB &SRVBIBMBR &MODULE &SRCFIL +
                          &ONBNDDIR &BNDDIR)

             DCL        VAR(&VAR1) TYPE(*INT) LEN(2)
             DCL        VAR(&POS) TYPE(*INT) LEN(2)
             DCL        VAR(&CPT) TYPE(*INT) LEN(2)
             DCL        VAR(&SRVPGMLIB) TYPE(*CHAR) LEN(20)
             DCL        VAR(&SRVPGM) TYPE(*CHAR) STG(*DEFINED) LEN(10) +
                          DEFVAR(&SRVPGMLIB 1)
             DCL        VAR(&SRVLIB) TYPE(*CHAR) STG(*DEFINED) LEN(10) +
                          DEFVAR(&SRVPGMLIB 11)
             DCL        VAR(&SRVBIBMBR) TYPE(*CHAR) LEN(30)
             DCL        VAR(&SRVFIC) TYPE(*CHAR) STG(*DEFINED) LEN(10) +
                          DEFVAR(&SRVBIBMBR 1)
             DCL        VAR(&SRVBIB) TYPE(*CHAR) STG(*DEFINED) LEN(10) +
                          DEFVAR(&SRVBIBMBR 11)
             DCL        VAR(&SRVMBR) TYPE(*CHAR) STG(*DEFINED) LEN(10) +
                          DEFVAR(&SRVBIBMBR 21)
             DCL        VAR(&MODULE) TYPE(*CHAR) LEN(102)
             DCL        VAR(&VALMOD) TYPE(*CHAR) LEN(10)
             DCL        VAR(&SRCFIL) TYPE(*CHAR) LEN(10)
             DCL        VAR(&ONBNDDIR) TYPE(*CHAR) LEN(1)
             DCL        VAR(&BNDDIR) TYPE(*CHAR) LEN(10)
             DCL        VAR(&LSTMOD) TYPE(*CHAR) LEN(250)
             DCL        VAR(&COMMANDE) TYPE(*CHAR) LEN(500)

             /* Initialiser les variables */
             CHGVAR     VAR(&VAR1) VALUE(%BIN(&MODULE 1 2))
             IF         COND(&SRVLIB *EQ '*CURLIB') THEN(RTVJOBA +
                          CURLIB(&SRVLIB))


             /* Extraction de chaque poste */
             DOFOR      VAR(&CPT) FROM(1) TO(&VAR1)
                CHGVAR     VAR(&POS) VALUE(3 + (&CPT - 1) * 10)
                CHGVAR     VAR(&VALMOD) VALUE(%SST(&MODULE &POS 10))

                CRTSQLRPGI OBJ(&SRVLIB/&VALMOD) SRCFILE(&SRVLIB/&SRCFIL) +
                             SRCMBR(&VALMOD) OBJTYPE(*MODULE) +
                             REPLACE(*YES) DBGVIEW(*SOURCE)

                CHGVAR     VAR(&LSTMOD) VALUE(%TRIM(&LSTMOD) !! ' ' !! +
                             %TRIM(&SRVLIB) !! '/' !! %TRIM(&VALMOD))

             ENDDO

             CHGVAR     VAR(&COMMANDE) VALUE('CRTSRVPGM  SRVPGM(' !! +
                          %TRIM(&SRVLIB) !! '/' !! %TRIM(&SRVPGM) !! ') +
                          MODULE(' !! %TRIM(&LSTMOD) !! ') +
                          EXPORT(*SRCFILE) SRCFILE(' !! %TRIM(&SRVBIB) !! +
                          '/' !! %TRIM(&SRVFIC) !! ') SRCMBR(' !! +
                          %TRIM(&SRVMBR) !! ')')

             CALL       PGM(QCMDEXC) PARM(&COMMANDE  %LEN(&COMMANDE))

             IF         COND(&ONBNDDIR = 'O') THEN(DO)
                CHKOBJ     OBJ(&SRVLIB/&BNDDIR) OBJTYPE(*BNDDIR)
                MONMSG     MSGID(CPF9801) EXEC(CRTBNDDIR  +
                             BNDDIR(&SRVLIB/&BNDDIR))
                ADDBNDDIRE BNDDIR(&SRVLIB/&BNDDIR) OBJ((&SRVLIB/&SRVPGM))
             ENDDO

             ENDPGM
/par